@echo off
setlocal enabledelayedexpansion
REM Netrinos Client Installer - Downloads and installs Netrinos for Windows
REM
REM Usage:
REM   install-client.bat [version]
REM
REM Version can be: daily, beta, latest (default)

REM Check for Administrator privileges
net session >nul 2>&1
if !errorlevel! neq 0 (
    echo Error: This script must be run as Administrator.
    exit /b 1
)

REM Get version from command line argument, default to latest
set "version=%~1"
if "%version%"=="" set "version=latest"

REM Set subfolder based on version
set "folder="
if /i "%version%"=="daily" set "folder=daily/"
if /i "%version%"=="beta" set "folder=beta/"

REM Download installer
set "url=https://dist.netrinos.com/windows/%folder%NetrinosInstaller-Windows_%version%.exe"
set "installer=%TEMP%\NetrinosInstaller.exe"
echo Downloading !url!...
curl.exe -fSL --progress-bar -o "%installer%" "!url!"
if !errorlevel! neq 0 (
    echo Download failed!
    exit /b 1
)

REM Write a temp script and launch it detached
set "logfile=%TEMP%\netrinos-install.log"
set "runner=%TEMP%\netrinos-run.cmd"
(
    echo @echo off
    echo "%installer%" /VERYSILENT /NORESTART /SUPPRESSMSGBOXES /LOG="%logfile%"
    echo del "%installer%" 2^>nul
    echo del "%runner%" 2^>nul
) > "%runner%"

echo Installing Netrinos %version%...
start "" /min "%runner%"
echo Install launched (safe if connection drops).
echo Install log: %logfile%